CGI.pm - a Perl5 CGI Library

Abstract

Everything is done through a ``CGI'' object. When you create one of these objects it examines the environment for a query string, parses it, and stores the results. You can then ask the CGI object to return or modify the query values. CGI objects handle POST and GET methods correctly, and correctly distinguish between scripts called from <ISINDEX> documents and form-based documents. In fact you can debug your script from the command line without worrying about setting up environment variables.

A script to create a fill-out form that remembers its state each time it's invoked is very easy to write with CGI.pm:

#!/usr/local/bin/perl

use CGI qw(:standard);

print header;
print start_html('A Simple Example'),
    h1('A Simple Example'),
    start_form,
    "What's your name? ",textfield('name'),
    p,
    "What's the combination?",
    p,
    checkbox_group(-name=>'words',
		   -values=>['eenie','meenie','minie','moe'],
		   -defaults=>['eenie','minie']),
    p,
    "What's your favorite color? ",
    popup_menu(-name=>'color',
	       -values=>['red','green','blue','chartreuse']),
    p,
    submit,
    end_form,
    hr;

if (param()) {
    print 
	"Your name is",em(param('name')),
	p,
	"The keywords are: ",em(join(", ",param('words'))),
	p,
	"Your favorite color is ",em(param('color')),
	hr;
}
print end_html;

Contents

Downloads

• Download gzip tar archive (Unix)
• Download pkzip archive (Windows)
• Download sit archive (Macintosh)
• Download just the CGI module (uncompressed)
• Archive of Old Versions

CGI.pm Version 3.01

• Download 3.01

Installation

• Download gzip tar archive (Unix)
• Download pkzip archive (Windows)
• Download sit archive (Macintosh)
• Download just the CGI module (uncompressed)

The current version of the software can always be downloaded from the master copy of this document maintained at http://stein.cshl.org/WWW/software/CGI/.

This package requires perl 5.004 or higher. Earlier versions of Perl may work, but CGI.pm has not been tested with them. If you're really stuck, edit the source code to remove the line that says "require 5.004", but don't be surprised if you run into problems.

If you are using a Unix system, you should have perl do the installation for you. Move to the directory containing CGI.pm and type the following commands:

   % perl Makefile.PL
   % make
   % make install

This will create two new files in your Perl library. CGI.pm is the main library file. Carp.pm (in the subdirectory "CGI") contains some optional utility routines for writing nicely formatted error messages into your server logs. See the Carp.pm man page for more details.

If you get error messages when you try to install, then you are either:

1. Running a Windows NT or Macintosh port of Perl that doesn't have make or the MakeMaker program built into it.
2. Have an old version of Perl. Upgrade to 5.004 or higher.

  > cd CGI.pm-2.73
  > copy CGI.pm C:\Perl\lib
  > mkdir C:\Perl\lib\CGI
  > copy CGI\*.pm C:\Perl\lib\CGI

For Macintosh users, just drag the file named CGI.pm into the folder where your other Perl .pm files are stored. Also drag the subfolder named "CGI".

If you do not have sufficient privileges to install into /usr/local/lib/perl5, you can still use CGI.pm. Modify the installation recipe as follows:

   % perl Makefile.PL INSTALLDIRS=site INSTALLSITELIB=/home/your/private/dir
   % make
   % make install

use lib '/home/your/private/dir';
use CGI;

Notes on using CGI.pm in NT and other non-Unix platforms

Function-Oriented vs Object-Oriented Use

#!/usr/local/bin/perl
use CGI qw/:standard/;
print header(),
      start_html(-title=>'Wow!'),
      h1('Wow!'),
      'Look Ma, no hands!',
      end_html();

In addition to the standard set, there are many optional sets of less frequently used CGI functions. See Importing CGI Methods for full details.

In the object-oriented mode, you use CGI; without specifying any functions or function sets to import. In this case, you communicate with CGI.pm via a CGI object. The object is created by a call to CGI::new() and encapsulates all the state information about the current CGI transaction, such as values of the CGI parameters passed to your script. Although more verbose, this coding style has the advantage of allowing you to create multiple CGI objects, save their state to disk or to a database, and otherwise manipulate them to achieve neat effects.

The same script written using the object-oriented style looks like this:

#!/usr/local/bin/perl
use CGI;
$q = new CGI;
print $q->header(),
      $q->start_html(-title=>'Wow!'),
      $q->h1('Wow!'),
      'Look Ma, no hands!',
      $q->end_html();

Many of the code examples below show the object-oriented coding style. Mentally translate them into the function-oriented style if you prefer.

Creating a new CGI object

    use CGI;
    $query = new CGI;

An alternative form of the new() method allows you to read script parameters from a previously-opened file handle:

    $query = new CGI(FILEHANDLE)

open (IN,"test.in") || die;
while (!eof(IN)) {
    my $q = new CGI(IN);
    push(@queries,$q);
}

    my $q = new CGI(\*IN);

If you are using the function-oriented interface and want to initialize CGI state from a file handle, the way to do this is with restore_parameters(). This will (re)initialize the default CGI object from the indicated file handle.

open (IN,"test.in") || die;
restore_parameters(IN);
close IN;

You can initialize a CGI object from an associative-array reference. Values can be either single- or multivalued:

$query = new CGI({'dinosaur'=>'barney',
                  'song'=>'I love you',
                  'friends'=>[qw/Jessica George Nancy/]});

$query = new CGI('dinosaur=barney&color=purple');

$old_query = new CGI;
$new_query = new CGI($old_query);

This form also allows you to create a CGI object that is initially empty:

$empty_query = new CGI('');

Fetching A List Of Keywords From The Query

    @keywords = $query->keywords

Fetching The Names Of All The Parameters Passed To Your Script

    @names = $query->param 

Fetching The Value(s) Of A Named Parameter

   @values = $query->param('foo');
             -or-
   $value = $query->param('foo');

If a value is not given in the query string, as in the queries "name1=&name2=" or "name1&name2", it will be returned as an empty string (not undef). This feature is new in 2.63, and was introduced to avoid multiple "undefined value" warnings when running with the -w switch.

Setting The Value(s) Of A Named Parameter

   $query->param('foo','an','array','of','values');
                   -or-
   $query->param(-name=>'foo',-values=>['an','array','of','values']);

The second example shows an alternative "named parameter" style of function call that is accepted by most of the CGI methods. See Calling CGI functions that Take Multiple Arguments for an explanation of this style.

Appending a Parameter

   $query->append(-name=>'foo',-values=>['yet','more','values']);

Deleting a Named Parameter Entirely

   $query->delete('foo');

Deleting all Parameters

   $query->delete_all();

Importing parameters into a namespace

   $query->import_names('R');
   print "Your name is $R::name\n"
   print "Your favorite colors are @R::colors\n";

If you don't specify a name space, this method assumes namespace "Q".

An optional second argument to import_names, if present and non-zero, will delete the contents of the namespace before loading it. This may be useful for environments like mod_perl in which the script does not exit after processing a request.

Warning: do not import into namespace 'main'. This represents a major security risk, as evil people could then use this feature to redefine central variables such as @INC. CGI.pm will exit with an error if you try to do this.

Direct Access to the Parameter List

$q->param_fetch('address')->[1] = '1313 Mockingbird Lane';
unshift @{$q->param_fetch(-name=>'address')},'George Munster';

You may call param_fetch() with the name of the CGI parameter, or with the -name argument, which has the same meaning as elsewhere.

Fetching the Parameter List as a Hash

$params = $q->Vars;
print $params->{'address'};
@foo = split("\0",$params->{'foo'});
%params = $q->Vars;

use CGI ':cgi-lib';
$params = Vars;

Many people want to fetch the entire parameter list as a hash in which the keys are the names of the CGI parameters, and the values are the parameters' values. The Vars() method does this. Called in a scalar context, it returns the parameter list as a tied hash reference. Changing a key changes the value of the parameter in the underlying CGI parameter list. Called in an array context, it returns the parameter list as an ordinary hash. This allows you to read the contents of the parameter list, but not to change it.

When using this, the thing you must watch out for are multivalued CGI parameters. Because a hash cannot distinguish between scalar and array context, multivalued parameters will be returned as a packed string, separated by the "\0" (null) character. You must split this packed string in order to get at the individual values. This is the convention introduced long ago by Steve Brenner in his cgi-lib.pl module for Perl version 4.

If you wish to use Vars() as a function, import the :cgi-lib set of function calls (also see the section on CGI-LIB compatibility).

RETRIEVING CGI ERRORS

Errors can occur while processing user input, particularly when processing uploaded files. When these errors occur, CGI will stop processing and return an empty parameter list. You can test for the existence and nature of errors using the cgi_error() function. The error messages are formatted as HTTP status codes. You can either incorporate the error text into an HTML page, or use it as the value of the HTTP status:

    my $error = $q->cgi_error;
    if ($error) {
	print $q->header(-status=>$error),
	      $q->start_html('Problems'),
              $q->h2('Request not processed'),
	      $q->strong($error);
        exit 0;
    }

When using the function-oriented interface (see the next section), errors may only occur the first time you call param(). Be prepared for this! Table of contents

Saving the Current State of a Form

Saving the State to a File

   $query->save(FILEHANDLE)

If you wish to use this method from the function-oriented (non-OO) interface, the exported name for this method is save_parameters(). See advanced techniques for more information.

Saving the State in a Self-Referencing URL

   $my_url=$query->self_url

If you'd like to get the URL without the entire query string appended to it, use the url() method:

   $my_self=$query->url

Obtaining the Script's URL

    $full_url      = $query->url();
    $full_url      = $query->url(-full=>1);  #alternative syntax
    $relative_url  = $query->url(-relative=>1);
    $absolute_url  = $query->url(-absolute=>1);
    $url_with_path = $query->url(-path_info=>1);
    $url_with_path_and_query = $query->url(-path_info=>1,-query=>1);

http://your.host.com/path/to/script.cgi

-absolute

If true, produce an absolute URL, e.g.

/path/to/script.cgi
      

-relative

Produce a relative URL. This is useful if you want to reinvoke your script with different parameters. For example:

    script.cgi

-full

Produce the full URL, exactly as if called without any arguments. This overrides the -relative and -absolute arguments.

-path,-path_info

Append the additional path information to the URL. This can be combined with -full, -absolute or -relative. -path_info is provided as a synonym.

-query (-query_string)

Append the query string to the URL. This can be combined with -full, -absolute or -relative. -query_string is provided as a synonym.

Mixing POST and URL Parameters

   $color = $query->url_param('color');

Under no circumstances will the contents of the URL query string interfere with similarly-named CGI parameters in POSTed forms. If you try to mix a URL query string with a form submitted with the GET method, the results will not be what you expect.

Table of contents

Calling CGI Functions that Take Multiple Arguments

   $field = $query->radio_group(-name=>'OS',
                                -values=>[Unix,Windows,Macintosh],
                                -default=>'Unix');

   $field = $query->textfield(-name=>'State',
                              -default=>'gaseous',
                              -justification=>'RIGHT');

   <INPUT TYPE="textfield" NAME="State" VALUE="gaseous"
          JUSTIFICATION="RIGHT">

HTML/HTTP parameters that contain internal hyphens, such as -Content-language can be passed by putting quotes around them, or by using an underscore for the second hyphen, e.g. -Content_language.

The fact that you must use curly {} braces around the attributes passed to functions that create simple HTML tags but don't use them around the arguments passed to all other functions has many people, including myself, confused. As of 2.37b7, the syntax is extended to allow you to use curly braces for all function calls:

   $field = $query->radio_group({-name=>'OS',
                                -values=>[Unix,Windows,Macintosh],
                                -default=>'Unix'});

Creating the HTTP Header

Creating the Standard Header for a Virtual Document

   print $query->header('image/gif');

An extended form of this method allows you to specify a status code and a message to pass back to the browser:

   print $query->header(-type=>'image/gif',
                        -status=>'204 No Response');

Several other named parameters are recognized. Here's a contrived example that uses them all:

   print $query->header(-type=>'image/gif',
                        -status=>'402 Payment Required',
                        -expires=>'+3d',
                        -cookie=>$my_cookie,
                        -charset=>'UTF-7',
                        -attachment=>'foo.gif',
                        -Cost=>'$0.02');

-expires

	+30s                              30 seconds from now
	+10m                              ten minutes from now
	+1h	                          one hour from now
        -1d                               yesterday (i.e. "ASAP!")
	now                               immediately
	+3M                               in three months
        +10y                              in ten years time
	Thu, 25-Apr-1999 00:40:33 GMT     at the indicated time & date

CGI::expires() is the static function call used internally that turns relative time intervals into HTTP dates. You can call it directly if you wish.

-cookie

-nph

print $query->header(-nph=>1,
                        -status=>'200 OK',
                        -type=>'text/html');

1. You are using Microsoft Internet Information Server.
2. If you need to create unbuffered output, for example for use in a "server push" script.
3. To take advantage of HTTP extensions not supported by your server.

-charset

-attachment

Other header fields

   Cost: $0.02

Creating the Header for a Redirection Request

   print $query->redirect('http://somewhere.else/in/the/world');

You can add your own headers to this as in the header() method.

You should always use absolute or full URLs in redirection requests. Relative URLs will not work correctly.

An alternative syntax for redirect() is:

print $query->redirect(-location=>'http://somewhere.else/',
                          -nph=>1);

The -nph parameter, if non-zero tells CGI.pm that this script is running as a no-parsed-header script. See Using NPH Scripts for more information.

The -method parameter tells the browser what method to use for redirection. This is handy if, for example, your script was called from a fill-out form POST operation, but you want to redirect the browser to a static page that requires a GET.

All other parameters recognized by the header() method are also valid in redirect. Table of contents

HTML Shortcuts

Creating an HTML Header

   named parameter style
   print $query->start_html(-title=>'Secrets of the Pyramids',
                            -author=>'fred@capricorn.org',
                            -base=>'true',
			    -meta=>{'keywords'=>'pharoah secret mummy',
                                    'copyright'=>'copyright 1996 King Tut'},
			    -style=>{'src'=>'/styles/style1.css'},
                            -dtd=>1,
                            -BGCOLOR=>'blue');

   old style
   print $query->start_html('Secrets of the Pyramids',
                            'fred@capricorn.org','true');

• The title (-title)
• The author's e-mail address (will create a <LINK REV="MADE"> tag if present (-author)
• A true flag if you want to include a <BASE> tag in the header (-base). This helps resolve relative addresses to absolute ones when the document is moved, but makes the document hierarchy non-portable. Use with care!
• A -xbase parameter, if you want to include a <BASE> tag that points to some external location. Example:

        print $query->start_html(-title=>'Secrets of the Pyramids',
                                 -xbase=>'http://www.nile.eg/pyramid.html');
        

• A -target parameter, if you want to have all links and fill out forms on the page go to a different frame. Example:

        print $query->start_html(-title=>'Secrets of the Pyramids',
                                 -target=>'answer_frame');
        

  -target can be used with either -xbase or -base.
• A -meta parameter to define one or more <META> tags. Pass this parameter a reference to an associative array containing key/value pairs. Each pair becomes a <META> tag in a format similar to this one.

        <META NAME="keywords" CONTENT="pharoah secret mummy">
        <META NAME="description" CONTENT="copyright 1996 King Tut">
        

  To create an HTTP-EQUIV tag, use the -head argument as described below.
• The -encoding argument can be used to specify the character set for XHTML. It defaults to iso-8859-1 if not specified.
• A -lang> argument is used to incorporate a language attribute into the <HTM>> tag. The default if not specified is "en-US" for US English. For example:

      print $q->start_html(-lang=>'fr-CA');
  

• A -dtd parameter to make start_html() generate an SGML document type definition for the document. This is used by SGML editors and high-end Web publishing systems to determine the type of the document. However, it breaks some browsers, in particular AOL's. The value of this parameter can be one of:
  1. A valid DTD (see http://ugweb.cs.ualberta.ca/%7egerald/validate/lib/catalog for a list). Example:

     -dtd=>'-//W3C//DTD HTML 3.2//EN'

  2. A true value that does not begin with "-//", in which case you will get the standard default DTD (valid for HTML 2.0).
  You can change the default DTD by calling default_dtd() with the preferred value.
• A -style parameter to define a cascading stylesheet. More information on this can be found in Limited Support for Cascading Style Sheets
• A -head parameter to define other arbitrary elements of the <HEAD> section. For example:

        print start_html(-head=>Link({-rel=>'next',
                         -href=>'http://www.capricorn.com/s2.html'}));
  
        

  or even

        print start_html(-head=>[ Link({-rel=>'next',
  			                 -href=>'http://www.capricorn.com/s2.html'}),
  			           Link({-rel=>'previous',
  				         -href=>'http://www.capricorn.com/s1.html'})
  			      ]
  		      );
        

  To create an HTTP-EQUIV tag, use something like this:

        print start_html(-head=>meta({-http_equiv=>'Content-Type',
                                         -content=>'text/html'}))
        

• A -script parameter to define Netscape JavaScript functions to incorporate into the HTML page. This is the preferred way to define a library of JavaScript functions that will be called from elsewhere within the page. CGI.pm will attempt to format the JavaScript code in such a way that non-Netscape browsers won't try to display the JavaScript code. Unfortunately some browsers get confused nevertheless. Here's an example of how to create a JavaScript library and incorporating it into the HTML code header:

        $query = new CGI;
        print $query->header;
        
        $JSCRIPT=<<END;
        // Ask a silly question
        function riddle_me_this() {
           var r = prompt("What walks on four legs in the morning, " +
                         "two legs in the afternoon, " +
                         "and three legs in the evening?");
           response(r);
        }
        // Get a silly answer
        function response(answer) {
           if (answer == "man")
              alert("Right you are!");
           else
              alert("Wrong!  Guess again.");
        }
        END
        
        print $query->start_html(-title=>'The Riddle of the Sphinx',
                                 -script=>$JSCRIPT);
        

  Netscape 3.0 and higher allows you to place the JavaScript code in an external document and refer to it by URL. This allows you to keep the JavaScript code in a file or CGI script rather than cluttering up each page with the source. Netscape 3.X-4.X and Internet Explorer 3.X-4.X also recognize a "language" parameter that allows you to use other languages, such as VBScript and PerlScript (yes indeed!) To use these attributes pass a HASH reference in the -script parameter containing one or more of the keys language, src, or code. Here's how to refer to an external script URL:

        print $q->start_html(-title=>'The Riddle of the Sphinx',
  			   -script=>{-language=>'JavaScript',
                                     -src=>'/javascript/sphinx.js'}
                                );
       

  Here's how to refer to scripting code incorporated directly into the page:

  
       print $q->start_html(-title=>'The Riddle of the Sphinx',
                            -script=>{-language=>'PerlScript',
                                      -code=>'print "hello world!\n;"'}
                               );
       

  A final feature allows you to incorporate multiple <SCRIPT> sections into the header. Just pass the list of script sections as an array reference. This allows you to specify different source files for different dialects of JavaScript. Example:

       print $q->start_html(-title=>'The Riddle of the Sphinx',
                            -script=>[
                                      { -language => 'JavaScript1.0',
                                        -src      => '/javascript/utilities10.js'
                                      },
                                      { -language => 'JavaScript1.1',
                                        -src      => '/javascript/utilities11.js'
                                      },
                                      { -language => 'JavaScript1.2',
                                        -src      => '/javascript/utilities12.js'
                                      },
                                      { -language => 'JavaScript28.2',
                                        -src      => '/javascript/utilities219.js'
                                      }
                                   ]
                               );
       

  (If this looks a bit extreme, take my advice and stick with straight CGI scripting.)

• A -noScript parameter to pass some HTML that will be displayed in browsers that do not have JavaScript (or have JavaScript turned off).
• -onLoad and -onUnload parameters to register JavaScript event handlers to be executed when the page generated by your script is opened and closed respectively. Example:

        print $query->start_html(-title=>'The Riddle of the Sphinx',
                                    -script=>$JSCRIPT,
                                    -onLoad=>'riddle_me_this()');
        

  See JavaScripting for more details.
• Any additional attributes you want to incorporate into the <BODY> tag (as many as you like). This is a good way to incorporate other Netscape extensions, such as background color and wallpaper pattern. (The example above sets the page background to a vibrant blue.) You can use this feature to take advantage of new HTML features without waiting for a CGI.pm release.

Ending an HTML Document

  print $query->end_html

Other HTML Tags

To see the list of HTML tags that are supported, open up the CGI.pm file and look at the functions defined in the %EXPORT_TAGS array.

Unpaired Tags

   print $query->hr;

Paired Tags

   print $query->em("What a silly art exhibit!");

You can pass as many text arguments as you like: they'll be concatenated together with spaces. This allows you to create nested tags easily:

   print $query->h3("The",$query->em("silly"),"art exhibit");

   <h3>The <em>silly</em> art exhibit</h3>

When used in conjunction with the import facility, the HTML shortcuts can make CGI scripts easier to read. For example:

   use CGI qw/:standard/;
   print h1("Road Guide"),
         ol(
          li(a({href=>"start.html"},"The beginning")),
          li(a({href=>"middle.html"},"The middle")),
          li(a({href=>"end.html"},"The end"))
         );

Most HTML tags are represented as lowercase function calls. There are a few exceptions:

1. The <tr> tag used to start a new table row conflicts with the perl translate function tr(). Use TR() or Tr() instead.
2. The <param> tag used to pass parameters to an applet conflicts with CGI's own param() method. Use PARAM() instead.
3. The <select> tag used to create selection lists conflicts with Perl's select() function. Use Select() instead.
4. The <sub> tag used to create subscripts conflicts wit Perl's operator for creating subroutines. Use Sub() instead.

Tags with Attributes

   use CGI qw/:standard/;
   print a({-href=>"bad_art.html"},"Jump to the silly exhibit");

   <A HREF="bad_art.html">Jump to the silly exhibit</A>

   print img {src=>'fred.gif',align=>'LEFT'};

   <IMG ALIGN="LEFT" SRC="fred.gif">

   print ol({compact=>undef},li('one'),li('two'),li('three'));

Distributive HTML Tags and Tables

print ul(
        li({-type=>'disc'},['Sneezy','Doc','Sleepy','Happy']);
      );

<UL>
  <LI TYPE="disc">Sneezy</LI>
  <LI TYPE="disc">Doc</LI>
  <LI TYPE="disc">Sleepy</LI>
  <LI TYPE="disc">Happy</LI>
</UL>

use CGI qw/:standard :html3/;
print table({-border=>undef},
        caption(strong('When Should You Eat Your Vegetables?')),
        Tr({-align=>CENTER,-valign=>TOP},
        [
           th(['','Breakfast','Lunch','Dinner']),
           th('Tomatoes').td(['no','yes','yes']),
           th('Broccoli').td(['no','no','yes']),
           th('Onions').td(['yes','yes','yes'])
        ]
      )
);

If you want to produce tables programatically, you can do it this way:

use CGI qw/:standard :html3/;
@values = (1..5);

@headings = ('N','N'.sup('2'),'N'.sup('3'));
@rows = th(\@headings);
foreach $n (@values) {
   push(@rows,td([$n,$n**2,$n**3]));
}
print table({-border=>undef,-width=>'25%'},
            caption(b('Wow.  I can multiply!')),
            Tr(\@rows)
           );

Creating Forms

General note 2. The default values that you specify for the forms are only used the first time the script is invoked. If there are already values present in the query string, they are used, even if blank.

If you want to change the value of a field from its previous value, you have two choices:

1. call the param() method to set it.
2. use the -override (alias -force) parameter. (This is a new feature in 2.15) This forces the default value to be used, regardless of the previous value of the field:

          print $query->textfield(-name=>'favorite_color',
                                  -default=>'red',
   			       -override=>1);
          

1. Create a special defaults button using the defaults() method.
2. Create a hypertext link that calls your script without any parameters.

General note 4. By popular demand, the text and labels that you provide for form elements are escaped according to HTML rules. This means that you can safely use "<CLICK ME>" as the label for a button. However, this behavior may interfere with your ability to incorporate special HTML character sequences, such as &Aacute; (Á) into your fields. If you wish to turn off automatic escaping, call the autoEscape() method with a false value immediately after creating the CGI object:

     $query = new CGI;
     $query->autoEscape(undef);

Form Elements

Creating An Isindex Tag

   print $query->isindex($action);

Starting And Ending A Form

   print $query->startform($method,$action,$encoding);
     ...various form stuff...
   print $query->endform;

The form encoding supports the "file upload" feature of Netscape 2.0 (and higher) and Internet Explorer 4.0 (and higher). The form encoding tells the browser how to package up the contents of the form in order to transmit it across the Internet. There are two types of encoding that you can specify:

application/x-www-form-urlencoded

This is the type of encoding used by all browsers prior to Netscape 2.0. It is compatible with many CGI scripts and is suitable for short fields containing text data. For your convenience, CGI.pm stores the name of this encoding type in $CGI::URL_ENCODED.

multipart/form-data

This is the newer type of encoding introduced by Netscape 2.0. It is suitable for forms that contain very large fields or that are intended for transferring binary data. Most importantly, it enables the "file upload" feature of Netscape 2.0 forms. For your convenience, CGI.pm stores the name of this encoding type in CGI::MULTIPART()

Forms that use this type of encoding are not easily interpreted by CGI scripts unless they use CGI.pm or another library that knows how to handle them. Unless you are using the file upload feature, there's no particular reason to use this type of encoding.

If you plan to make use of the JavaScript features, you can provide startform() with the optional -name and/or -onSubmit parameters. -name has no effect on the display of the form, but can be used to give the form an identifier so that it can be manipulated by JavaScript functions. Provide the -onSubmit parameter in order to register some JavaScript code to be performed just before the form is submitted. This is useful for checking the validity of a form before submitting it. Your JavaScript code should return a value of "true" to let Netscape know that it can go ahead and submit the form, and "false" to abort the submission.

Starting a Form that Uses the "File Upload" Feature

   print $query->start_multipart_form($method,$action,$encoding);
     ...various form stuff...
   print $query->endform;

Creating A Text Field

  Named parameter style
  print $query->textfield(-name=>'field_name',
	                    -default=>'starting value',
	                    -size=>50,
	                    -maxlength=>80);

   Old style
  print $query->textfield('foo','starting value',50,80);

• The first parameter (-name) is the required name for the field.
• The optional second parameter (-default) is the starting value for the field contents.
• The optional third parameter (-size) is the size of the field in characters.
• The optional fourth parameter (-maxlength) is the maximum number of characters the field will accomodate.

When the form is processed, the value of the text field can be retrieved with:

      $value = $query->param('foo');

JavaScripting: You can also provide -onChange, -onFocus, -onBlur, -onMouseOver, -onMouseOut and -onSelect parameters to register JavaScript event handlers.

Creating A Big Text Field

   Named parameter style
   print $query->textarea(-name=>'foo',
	 		  -default=>'starting value',
	                  -rows=>10,
	                  -columns=>50);

   Old style
   print $query->textarea('foo','starting value',10,50);

JavaScripting: Like textfield(), you can provide -onChange, -onFocus, -onBlur, -onMouseOver, -onMouseOut and -onSelect parameters to register JavaScript event handlers.

Creating A Password Field

   Named parameter style
   print $query->password_field(-name=>'secret',
				-value=>'starting value',
				-size=>50,
				-maxlength=>80);

   Old style
   print $query->password_field('secret','starting value',50,80);

Creating a File Upload Field

    Named parameters style
    print $query->filefield(-name=>'uploaded_file',
	                    -default=>'starting value',
	                    -size=>50,
	 		    -maxlength=>80);

    Old style
    print $query->filefield('uploaded_file','starting value',50,80);

• The first parameter (-name) is the required name for the field.
• The optional second parameter (-default) is the starting value for the file name. This field is currently ignored by all browsers, but there's always hope!
• The optional third parameter (-size) is the size of the field in characters.
• The optional fourth parameter (-maxlength) is the maximum number of characters the field will accomodate.

In order to take full advantage of the file upload facility you must use the new multipart form encoding scheme. You can do this either by calling startform() and specify an encoding type of $CGI::MULTIPART or by using the new start_multipart_form() method. If you don't use multipart encoding, then you'll be able to retreive the name of the file selected by the remote user, but you won't be able to access its contents.

When the form is processed, you can retrieve the entered filename by calling param().

       $filename = $query->param('uploaded_file');

The filename returned is also a file handle. You can read the contents of the file using standard Perl file reading calls:

	# Read a text file and print it out
	while (<$filename>) {
	   print;
        }

        # Copy a binary file to somewhere safe
        open (OUTFILE,">>/usr/local/web/users/feedback");
	while ($bytesread=read($filename,$buffer,1024)) {
	   print OUTFILE $buffer;
        }
       close $filename;

There are problems with the dual nature of the upload fields. If you use strict, then Perl will complain when you try to use a string as a filehandle. You can get around this by placing the file reading code in a block containing the no strict pragma. More seriously, it is possible for the remote user to type garbage into the upload field, in which case what you get from param() is not a filehandle at all, but a string.

To be safe, use the upload() function (new in version 2.47). When called with the name of an upload field, upload() returns a filehandle, or undef if the parameter is not a valid filehandle.

     $fh = $query->upload('uploaded_file');
     while (<$fh>) {
	   print;
     }

In an array context, upload() will return an array of filehandles. This makes it possible to create forms that use the same name for multiple upload fields.

This is the recommended idiom.

You can have several file upload fields in the same form, and even give them the same name if you like (in the latter case param() will return a list of file names). However, if the user attempts to upload several files with exactly the same name, CGI.pm will only return the last of them. This is a known bug.

When processing an uploaded file, CGI.pm creates a temporary file on your hard disk and passes you a file handle to that file. After you are finished with the file handle, CGI.pm unlinks (deletes) the temporary file. If you need to you can access the temporary file directly. Its name is stored inside the CGI object's "private" data, and you can access it by passing the file name to the tmpFileName() method:

       $filename = $query->param('uploaded_file');
       $tmpfilename = $query->tmpFileName($filename);

The temporary file will be deleted automatically when your program exits unless you manually rename it. On some operating systems (such as Windows NT), you will need to close the temporary file's filehandle before your program exits. Otherwise the attempt to delete the temporary file will fail.

A potential problem with the temporary file upload feature is that the temporary file is accessible to any local user on the system. In previous versions of this module, the temporary file was world readable, meaning that anyone could peak at what was being uploaded. As of version 2.36, the modes on the temp file have been changed to read/write by owner only. Only the Web server and its CGI scripts can access the temp file. Unfortunately this means that one CGI script can spy on another! To make the temporary files really private, set the CGI global variable $CGI::PRIVATE_TEMPFILES to 1. Alternatively, call the built-in function CGI::private_tempfiles(1), or just use CGI qw/-private_tempfiles. The temp file will now be unlinked as soon as it is created, making it inaccessible to other users. The downside of this is that you will be unable to access this temporary file directly (tmpFileName() will continue to return a string, but you will find no file at that location.) Further, since PRIVATE_TEMPFILES is a global variable, its setting will affect all instances of CGI.pm if you are running mod_perl. You can work around this limitation by declaring $CGI::PRIVATE_TEMPFILES as a local at the top of your script.

On Windows NT, it is impossible to make a temporary file private. This is because Windows doesn't allow you to delete a file before closing it.

Usually the browser sends along some header information along with the text of the file itself. Currently the headers contain only the original file name and the MIME content type (if known). Future browsers might send other information as well (such as modification date and size). To retrieve this information, call uploadInfo(). It returns a reference to an associative array containing all the document headers. For example, this code fragment retrieves the MIME type of the uploaded file (be careful to use the proper capitalization for "Content-Type"!):

       $filename = $query->param('uploaded_file');
       $type = $query->uploadInfo($filename)->{'Content-Type'};
       unless ($type eq 'text/html') {
	  die "HTML FILES ONLY!";
       }

JavaScripting: Like textfield(), filefield() accepts -onChange, -onFocus, -onBlur, -onMouseOver, -onMouseOut and -onSelect parameters to register JavaScript event handlers. Caveats and potential problems in the file upload feature.

Creating A Popup Menu

  Named parameter style
  print $query->popup_menu(-name=>'menu_name',
                            -values=>[qw/eenie meenie minie/], 
			    -labels=>{'eenie'=>'one',
                                         'meenie'=>'two',
                                         'minie'=>'three'},
	                    -default=>'meenie');

  print $query->popup_menu(-name=>'menu_name',
			    -values=>['eenie','meenie','minie'],
	                    -default=>'meenie');
  
  Old style
  print $query->popup_menu('menu_name',
                              ['eenie','meenie','minie'],'meenie',
                              {'eenie'=>'one','meenie'=>'two','minie'=>'three'});

• The required first argument (-name) is the menu's name.
• The required second argument (-values) is an array reference containing the list of menu items in the menu. You can pass the method an anonymous array, as shown in the example, or a reference to a named array, such as \@foo. If you pass a HASH reference, the keys will be used for the menu values, and the values will be used for the menu labels (see -labels below).
• The optional third parameter (-default) is the name of the default menu choice. If not specified, the first item will be the default. The value of the previous choice will be maintained across queries.
• The optional fourth parameter (-labels) allows you to pass a reference to an associative array containing user-visible labels for one or more of the menu items. You can use this when you want the user to see one menu string, but have the browser return your program a different one. If you don't specify this, the value string will be used instead ("eenie", "meenie" and "minie" in this example). This is equivalent to using a hash reference for the -values parameter.

     $popup_menu_value = $query->param('menu_name');

Creating A Scrolling List

   Named parameter style
   print $query->scrolling_list(-name=>'list_name',
                                -values=>['eenie','meenie','minie','moe'],
                                -default=>['eenie','moe'],
	                        -size=>5,
	                        -multiple=>'true',
                                -labels=>\%labels);

   Old style
   print $query->scrolling_list('list_name',
                                ['eenie','meenie','minie','moe'],
                                ['eenie','moe'],5,'true',
                                \%labels);

• The first and second arguments (-name, -values)are the list name and values, respectively. As in the popup menu, the second argument should be an array reference or hash reference. In the latter case, the values of the hash are used as the human-readable labels in the list.
• The optional third argument (-default)can be either a reference to a list containing the values to be selected by default, or can be a single value to select. If this argument is missing or undefined, then nothing is selected when the list first appears.
• The optional fourth argument (-size) is the display size of the list.
• The optional fifth argument (-multiple) can be set to true to allow multiple simultaneous selections.
• The option sixth argument (-labels) can be used to assign user-visible labels to the list items different from the ones used for the values as above. This is equivalent to passing a hash reference to -values. In this example we assume that an associative array %labels has already been created.

     @selected = $query->param('list_name');

Creating A Group Of Related Checkboxes

   Named parameter style
   print $query->checkbox_group(-name=>'group_name',
                                -values=>['eenie','meenie','minie','moe'],
                                -default=>['eenie','moe'],
	                        -linebreak=>'true',
	                        -labels=>\%labels);

   Old Style
   print $query->checkbox_group('group_name',
                                ['eenie','meenie','minie','moe'],
                                ['eenie','moe'],'true',\%labels);

   HTML3 Browsers Only
   print $query->checkbox_group(-name=>'group_name',
                                -values=>['eenie','meenie','minie','moe'],
                                -rows=>2,-columns=>2);

• The first and second arguments (-name, -values) are the checkbox name and values, respectively. As in the popup menu, the second argument should be an array reference or a hash reference. These values are used for the user-readable labels printed next to the checkboxes as well as for the values passed to your script in the query string.
• The optional third argument (-default) can be either a reference to a list containing the values to be checked by default, or can be a single value to checked. If this argument is missing or undefined, then nothing is selected when the list first appears.
• The optional fourth argument (-linebreak) can be set to true to place line breaks between the checkboxes so that they appear as a vertical list. Otherwise, they will be strung together on a horizontal line. When the form is procesed, all checked boxes will be returned as a list under the parameter name 'group_name'. The values of the "on" checkboxes can be retrieved with:
• The optional fifth argument (-labels) is a reference to an hash of checkbox labels. This allows you to use different strings for the user-visible button labels and the values sent to your script. In this example we assume that an associative array %labels has previously been created. This is equivalent to passing a hash reference to -values. If you don't use -nolabels, CGI.pm will add HTML label tag around each checkbox and its label, so a browser can identify the text as form element label properly.
• The optional parameter -nolabels can be used to suppress the printing of labels next to the button. This is useful if you want to capture the button elements individually and use them inside labeled HTML3 tables.
• Browsers that understand HTML3 tables (such as Netscape) can take advantage of the optional parameters -rows, and -columns. These parameters cause checkbox_group() to return an HTML3 compatible table containing the checkbox group formatted with the specified number of rows and columns. You can provide just the -columns parameter if you wish; checkbox_group will calculate the correct number of rows for you.

  To include row and column headings in the returned table, you can use the -rowheaders and -colheaders parameters. Both of these accept a pointer to an array of headings to use. The headings are just decorative. They don't reorganize the interpetation of the checkboxes -- they're still a single named unit.

  When viewed with browsers that don't understand HTML3 tables, the -rows and -columns parameters will leave you with a group of buttons that may be awkwardly formatted but still useable. However, if you add row and/or column headings, the resulting text will be very hard to read.

     @turned_on = $query->param('group_name');

       @h = $query->checkbox_group(-name=>'choice',
                                    -value=>['fee','fie','foe'],
                                    -nolabels=>1);
       create_nice_table(@h);

Creating A Standalone Checkbox

   Named parameter list
   print $query->checkbox(-name=>'checkbox_name',
			   -checked=>'checked',
		           -value=>'TURNED ON',
		           -label=>'Turn me on');

   Old style
   print $query->checkbox('checkbox_name',1,'TURNED ON','Turn me on');

• The first parameter (-name is the required name for the checkbox. It will also be used for the user-readable label printed next to the checkbox.
• The optional second parameter (-checked specifies that the checkbox is turned on by default. Aliases for this parameter are -selected and -on.
• The optional third parameter (-value specifies the value of the checkbox when it is checked. If not provided, the word "on" is assumed.
• The optional fourth parameter (-label assigns a user-visible label to the button. If not provided, the checkbox's name will be used. CGI.pm will add HTML label tag around the checkbox and its label, so a browser can identify the text as form element label properly.

     $turned_on = $query->param('checkbox_name');

Creating A Radio Button Group

   Named parameter style
   print $query->radio_group(-name=>'group_name',
			     -values=>['eenie','meenie','minie'],
                             -default=>'meenie',
			     -linebreak=>'true',
			     -labels=>\%labels);

   Old style
   print $query->radio_group('group_name',['eenie','meenie','minie'],
                                          'meenie','true',\%labels);

   HTML3-compatible browsers only
   print $query->radio_group(-name=>'group_name',
                                -values=>['eenie','meenie','minie','moe'],
	                        -rows=>2,-columns=>2);

• The first argument (-name is the name of the group and is required.
• The second argument (-values is the list of values for the radio buttons. The values and the labels that appear on the page are identical. Pass an array reference in the second argument, either using an anonymous array, as shown, or by referencing a named array as in \@foo. You may also use a hash reference in order to produce human-readable labels that are different from the values that will be returned as parameters to the CGI script.
• The optional third parameter (-default is the value of the default button to turn on. If not specified, the first item will be the default. Specify some nonexistent value, such as "-" if you don't want any button to be turned on.
• The optional fourth parameter (-linebreak can be set to 'true' to put line breaks between the buttons, creating a vertical list.
• The optional fifth parameter (-labels specifies an associative array containing labels to be printed next to each button. If not provided the button value will be used instead. This example assumes that the associative array %labels has already been defined. This is equivalent to passing a hash reference to -values. If you don't use -nolabels, CGI.pm will add HTML label tag around each radio button and its label, so a browser can identify the text as form element label properly.
• The optional parameter -nolabels can be used to suppress the printing of labels next to the button. This is useful if you want to capture the button elements individually and use them inside labeled HTML3 tables.
• Browsers that understand HTML3 tables (such as Netscape) can take advantage of the optional parameters -rows, and -columns. These parameters cause radio_group() to return an HTML3 compatible table containing the radio cluster formatted with the specified number of rows and columns. You can provide just the -columns parameter if you wish; radio_group will calculate the correct number of rows for you.

  To include row and column headings in the returned table, you can use the -rowheader and -colheader parameters. Both of these accept a pointer to an array of headings to use. The headings are just decorative. They don't reorganize the interpetation of the radio buttons -- they're still a single named unit.

  When viewed with browsers that don't understand HTML3 tables, the -rows and -columns parameters will leave you with a group of buttons that may be awkwardly formatted but still useable. However, if you add row and/or column headings, the resulting text will be very hard to read.

       $which_radio_button = $query->param('group_name');

       @h = $query->radio_group(-name=>'choice',
                                 -value=>['fee','fie','foe'],
                                 -nolabels=>1);
       create_nice_table(@h);

JavaScripting: You can provide an -onClick parameter to register some JavaScript code to be performed every time the user clicks on any of the buttons in the group.

Creating A Submit Button

   Named parameter style
   print $query->submit(-name=>'button_name',
		        -value=>'value');

  Old style
  print $query->submit('button_name','value');

• The first argument (-nameis optional. You can give the button a name if you have several submission buttons in your form and you want to distinguish between them.
• The second argument (-valueis also optional. This gives the button a value that will be passed to your script in the query string, and will also appear as the user-visible label.

  You can figure out which of several buttons was pressed by using different values for each one:

      $which_one = $query->param('button_name');
  

• You can use -label as an alias for -value. I always get confused about which of -name and -value changes the user-visible label on the button.

Creating A Reset Button

  print $query->reset

Creating A Defaults Button

  print $query->defaults('button_label')

Creating A Hidden Field

   Named parameter style
   print $query->hidden(-name=>'hidden_name',
                        -default=>['value1','value2'...]);

   Old style
   print $query->hidden('hidden_name','value1','value2'...);

• The first argument (-name) is required and specifies the name of this field.
• The second and subsequent arguments specify the value for the hidden field. This is a quick and dirty way of passing perl arrays through forms. If you use the named parameter style, you must provide the parameter -default and an array reference here.

As of version 2.0 I have changed the behavior of hidden fields once again. Read this if you use hidden fields.

Hidden fields used to behave differently from all other fields: the provided default values always overrode the "sticky" values. This was the behavior people seemed to expect, however it turns out to make it harder to write state-maintaining forms such as shopping cart programs. Therefore I have made the behavior consistent with other fields.

Just like all the other form elements, the value of a hidden field is "sticky". If you want to replace a hidden field with some other values after the script has been called once you'll have to do it manually before writing out the form element:

     $query->param('hidden_name','new','values','here');
     print $query->hidden('hidden_name');

    $hidden_value = $query->param('hidden_name');
            -or (for values created with arrays)-
    @hidden_values = $query->param('hidden_name');

Creating a Clickable Image Button

   Named parameter style
   print $query->image_button(-name=>'button_name',
                              -src=>'/images/NYNY.gif',
                              -align=>'MIDDLE');	

   Old style
   print $query->image_button('button_name','/source/URL','MIDDLE');

• The first argument(-name is required and specifies the name of this field.
• The second argument (-srcspecifies the URL of the image to display. It must be one of the types supported by inline images (e.g. GIF), but can be any local or remote URL.
• The third argument (-alignis anything you might want to use in the ALIGN attribute, such as TOP, BOTTOM, LEFT, RIGHT or MIDDLE. This field is optional.

    $x = $query->param('button_name.x');
    $y = $query->param('button_name.y');

Creating a JavaScript Button

   Named parameter style
   print $query->button(-name=>'button1',
                           -value=>'Click Me',
                           -onClick=>'doButton(this)');	

   Old style
   print $query->image_button('button1','Click Me','doButton(this)');

• The first argument(-name is required and specifies the name of this field.
• The second argument (-value gives the button a value, and will be used as the user-visible label on the button.
• The third argument (-onClick is any valid JavaScript code. It's usually a call to a JavaScript function defined somewhere else (see the start_html() method), but can be any JavaScript you like. Multiple lines are allowed, but you must be careful not to include any double quotes in the JavaScript text.

Controlling HTML Autoescaping

Use

    $query->autoEscape(undef);

    $query->autoEscape('true');

Importing CGI Methods

use CGI qw(:standard);

use CGI;
$dinner = $query->param('entree');

use CGI qw(:standard);
$dinner = param('entree');

print $query->start_form,
      "Check here if you're happy: ",
      $query->checkbox(-name=>'happy',-value=>'Y',-checked=>1),
      "<P>",
      $query->submit,
      $query->end_form;

print start_form,
      "Check here if you're happy: ",
      checkbox(-name=>'happy',-value=>'Y',-checked=>1),
      p,
      submit,
      end_form;

$CGI::Q;

The use CGI statement is used to import method names into the current name space. There is a slight overhead for each name you import, but ordinarily is nothing to worry about. You can import selected method names like this:

   use CGI qw(header start_html end_html);

use CGI qw(:cgi :html2);

:cgi

These are all the tags that support one feature or another of the CGI protocol, including param(), path_info(), cookie(), request_method(), header() and the like.

:form

These are all the form element-generating methods, including start_form(), textfield(), etc.

:html2

These are HTML2-defined shortcuts such as br(), p() and head(). It also includes such things as start_html() and end_html() that aren't exactly HTML2, but are close enough.

:html3

These contain various HTML3 tags for tables, frames, super- and subscripts, applets and other objects.

:html4

These contain various HTML4 tags, including table headers and footers.

:netscape

These are Netscape extensions not included in the HTML3 category including blink() and center().

:html

These are all the HTML generating shortcuts, comprising the union of html2, html3, and netscape.

:multipart

These are various functions that simplify creating documents of the various multipart MIME types, and are useful for implementing server push.

:standard

This is the union of html2, html3, html4, form, and :cgi.

:all

This imports all the public methods into your namespace!

Pragmas

-any

When you use CGI -any, then any method that the query object doesn't recognize will be interpreted as a new HTML tag. This allows you to support the next ad hoc Netscape or Microsoft HTML extension. For example, to support Netscape's latest tag, <GRADIENT> (which causes the user's desktop to be flooded with a rotating gradient fill until his machine reboots), you can use something like this:

      use CGI qw(-any);
      $q=new CGI;
      print $q->gradient({speed=>'fast',start=>'red',end=>'blue'});
      

Since using any causes any mistyped method name to be interpreted as an HTML tag, use it with care or not at all.

-compile

This causes the indicated autoloaded methods to be compiled up front, rather than deferred to later. This is useful for scripts that run for an extended period of time under FastCGI or mod_perl, and for those destined to be crunched by Malcom Beattie's Perl compiler. Use it in conjunction with the methods or method familes you plan to use.

      use CGI qw(-compile :standard :html3);
      

or even

      use CGI qw(-compile :all);
      

Note that using the -compile pragma in this way will always have the effect of importing the compiled functions into the current namespace. If you want to compile without importing use the compile() method instead.

-autoload

Overrides the autoloader so that any function in your program that is not recognized is referred to CGI.pm for possible evaluation. This allows you to use all the CGI.pm functions without adding them to your symbol table, which is of concern for mod_perl users who are worried about memory consumption. Warning: when -autoload is in effect, you cannot use "poetry mode" (functions without the parenthesis). Use hr() rather than hr, or add something like use subs qw/hr p header/ to the top of your script.

-nosticky

Turns off "sticky" behavior in fill-out forms. Every form element will act as if you passed -override.

-no_xhtml

By default, CGI.pm versions 2.69 and higher emit XHTML (http://www.w3.org/TR/xhtml1/). The -no_xhtml pragma disables this feature. Thanks to Michalis Kabrianis <kabrianis@hellug.gr> for this feature.

-nph

This makes CGI.pm produce a header appropriate for an NPH (no parsed header) script. You may need to do other things as well to tell the server that the script is NPH. See the discussion of NPH scripts below.

-oldstyle_urls

Separate the name=value pairs in CGI parameter query strings emitted by self_url() and query_string() with ampersands. Otherwise, CGI.pm emits HTML-compliant semicolons. If you use this form, be sure to escape ampersands into HTML entities with escapeHTML. Example:

      $href = $q->self_url();
      $href = escapeHTML($href);
      print I'm talking to myself
      

-newstyle_urls

Separate the name=value pairs in CGI parameter query strings with semicolons rather than ampersands. For example:

      name=fred;age=24;favorite_color=3
      

As of version 2.64, this is the default style.

-no_debug

This turns off the command-line processing features. If you want to run a CGI.pm script from the command line to produce HTML, and you don't want it interpreting arguments on the command line as CGI name=value arguments, then use this pragma:

      use CGI qw(-no_debug :standard);
      

-debug

This turns on full debugging. In addition to reading CGI arguments from the command-line processing, CGI.pm will pause and try to read arguments from STDIN, producing the message "(offline mode: enter name=value pairs on standard input)" features.

See debugging for more details.

-private_tempfiles

CGI.pm can process uploaded file. Ordinarily it spools the uploaded file to a temporary directory, then deletes the file when done. However, this opens the risk of eavesdropping as described in the file upload section. Another CGI script author could peek at this data during the upload, even if it is confidential information. On Unix systems, the -private_tempfiles pragma will cause the temporary file to be unlinked as soon as it is opened and before any data is written into it, eliminating the risk of eavesdropping.

Special Forms for Importing HTML-Tag Functions

  print h1('Level 1 Header');

  <H1>Level 1 Header</H1>

  print start_h1,'Level 1 Header',end_h1;

Example:

  use CGI qw/:standard *table start_ul/;

1. start_table() (generates a <TABLE> tag)
2. end_table() (generates a </TABLE> tag)
3. start_ul() (generates a <UL> tag)
4. end_ul() (generates a </UL> tag)

AUTOESCAPING HTML

$escaped_string = escapeHTML("unescaped string");

Provided that you have specified a character set of ISO-8859-1 (the default), the standard HTML escaping rules will be used. The "<" character becomes "&lt;", ">" becomes "&gt;", "&" becomes "&amp;", and the quote character becomes "&quot;". In addition, the hexadecimal 0x8b and 0x9b characters, which many windows-based browsers interpret as the left and right angle-bracket characters, are replaced by their numeric HTML entities ("&#139" and "&#155;"). If you manually change the charset, either by calling the charset() method explicitly or by passing a -charset argument to header(), then all characters will be replaced by their numeric entities, since CGI.pm has no lookup table for all the possible encodings.

Autoescaping does not apply to other HTML-generating functions, such as h1(). You should call escapeHTML() yourself on any data that is passed in from the outside, such as nasty text that people may enter into guestbooks.

To change the character set, use charset(). To turn autoescaping off completely, use autoescape():

$charset = charset([$charset]);  # Get or set the current character set.

$flag = autoEscape([$flag]);     # Get or set the value of the autoescape flag.

PRETTY-PRINTING HTML

Optional Utility Functions

escape(), unescape()

use CGI qw/escape unescape/;
$q = escape('This $string contains ~wonderful~ characters');
$u = unescape($q);

escapeHTML(), unescapeHTML()

use CGI qw/escapeHTML unescapeHTML/;
$q = escapeHTML('This string is <illegal> html!');
$u = unescapeHTML($q);

compile()

use CGI ();
CGI->compile(':all');

Debugging

   my_script.pl keyword1 keyword2 keyword3

   my_script.pl keyword1+keyword2+keyword3

   my_script.pl name1=value1 name2=value2

   my_script.pl name1=value1&name2=value2

   % my_script.pl
   first_name=fred
   last_name=flintstone
   occupation='granite miner'
   ^D

When debugging, you can use quotation marks and the backslash character to escape spaces and other funny characters in exactly the way you would in the shell (which isn't surprising since CGI.pm uses "shellwords.pl" internally). This lets you do this sort of thing:

    my_script.pl 'name 1=I am a long value' name\ 2=two\ words

If you run a script that uses CGI.pm from the command line and fail to provide it with any arguments, it will print out the line

(offline mode: enter name=value pairs on standard input)

You can suppress this behavior in any of the following ways:

1. Call the script with an empty parameter.

Example:

      my_script.pl ''
      

2. Redirect standard input from /dev/null or an empty file.

Example:

      my_script.pl </dev/null
      

3. Include "-no_debug" in the list of symbols to import on the "use" line.

Example:

      use CGI qw/:standard -no_debug/;
      

Dumping Out All The Name/Value Pairs

   print $query->Dump

   <UL>
   <LI>name1
       <UL>
       <LI>value1
       <LI>value2
       </UL>
   <LI>name2
       <UL>
       <LI>value1
       </UL>
   </UL>

   print "<H2>Current Contents:</H2>\n$query\n";

HTTP Session Variables

Accept()

Return a list of MIME types that the remote browser accepts. If you give this method a single argument corresponding to a MIME type, as in $query->Accept('text/html'), it will return a floating point value corresponding to the browser's preference for this type from 0.0 (don't want) to 1.0. Glob types (e.g. text/*) in the browser's accept list are handled correctly. Note the capitalization of the initial letter. This avoids conflict with the Perl built-in accept().

auth_type()

Return the authorization type, if protection is active. Example "Basic".

raw_cookie()

Returns the "magic cookie" maintained by Netscape 1.1 and higher in a raw state. You'll probably want to use cookie() instead, which gives you a high-level interface to the cookie functions. Called with no parameters, raw_cookie() returns the entire cookie structure, which may consist of several cookies appended together (you can recover individual cookies by splitting on the "; " sequence. Called with the name of a cookie, returns the unescaped value of the cookie as set by the server. This may be useful for retrieving cookies that your script did not set.

path_info()

Returns additional path information from the script URL. E.G. fetching /cgi-bin/your_script/additional/stuff will result in $query->path_info() returning "/additional/stuff". In addition to reading the path information, you can set it by giving path_info() an optional string argument. The argument is expected to begin with a "/". If not present, one will be added for you. The new path information will be returned by subsequent calls to path_info(), and will be incorporated into the URL generated by self_url().

path_translated()

As per path_info() but returns the additional path information translated into a physical path, e.g. "/usr/local/etc/httpd/htdocs/additional/stuff". You cannot change the path_translated, nor will setting the additional path information change this value. The reason for this restriction is that the translation of path information into a physical path is ordinarily done by the server in a layer that is inaccessible to CGI scripts.

query_string()

Returns a query string suitable for maintaining state.

referer()

Return the URL of the page the browser was viewing prior to fetching your script. Not available for all browsers.

remote_addr()

Return the dotted IP address of the remote host.

remote_ident()

Return the identity-checking information from the remote host. Only available if the remote host has the identd daemon turned on.

remote_host()

Returns either the remote host name or IP address. if the former is unavailable.

remote_user()

Return the name given by the remote user during password authorization.

request_method()

Return the HTTP method used to request your script's URL, usually one of GET, POST, or HEAD.

script_name()

Return the script name as a partial URL, for self-refering scripts.

server_name()

Return the name of the WWW server the script is running under.

server_software()

Return the name and version of the server software.

virtual_host()

When using the virtual host feature of some servers, returns the name of the virtual host the browser is accessing.

server_port()

Return the communications port the server is using.

user_agent()

Returns the identity of the remote user's browser software, e.g. "Mozilla/1.1N (Macintosh; I; 68K)"

user_name()

Attempts to obtain the remote user's name, using a variety of environment variables. This only works with older browsers such as Mosaic. Netscape does not reliably report the user name!

http()

Called with no arguments returns the list of HTTP environment variables, including such things as HTTP_USER_AGENT, HTTP_ACCEPT_LANGUAGE, and HTTP_ACCEPT_CHARSET, corresponding to the like-named HTTP header fields in the request. Called with the name of an HTTP header field, returns its value. Capitalization and the use of hyphens versus underscores are not significant.

For example, all three of these examples are equivalent:

   $requested_language = $q->http('Accept-language');
   $requested_language = $q->http('Accept_language');
   $requested_language = $q->http('HTTP_ACCEPT_LANGUAGE');

https()

The same as http(), but operates on the HTTPS environment variables present when the SSL protocol is in effect. Can be used to determine whether SSL is turned on.

HTTP Cookies

A cookie is a name=value pair much like the named parameters in a CGI query string. CGI scripts create one or more cookies and send them to the browser in the HTTP header. The browser maintains a list of cookies that belong to a particular Web server, and returns them to the CGI script during subsequent interactions.

In addition to the required name=value pair, each cookie has several optional attributes:

an expiration time

This is a time/date string (in a special GMT format) that indicates when a cookie expires. The cookie will be saved and returned to your script until this expiration date is reached if the user exits the browser and restarts it. If an expiration date isn't specified, the cookie will remain active until the user quits the browser.

Negative expiration times (e.g. "-1d") cause some browsers to delete the cookie from its persistent store. This is a poorly documented feature.

a domain

This is a partial or complete domain name for which the cookie is valid. The browser will return the cookie to any host that matches the partial domain name. For example, if you specify a domain name of ".capricorn.com", then the browser will return the cookie to Web servers running on any of the machines "www.capricorn.com", "www2.capricorn.com", "feckless.capricorn.com", etc. Domain names must contain at least two periods to prevent attempts to match on top level domains like ".edu". If no domain is specified, then the browser will only return the cookie to servers on the host the cookie originated from.

a path

If you provide a cookie path attribute, the browser will check it against your script's URL before returning the cookie. For example, if you specify the path "/cgi-bin", then the cookie will be returned to each of the scripts "/cgi-bin/tally.pl", "/cgi-bin/order.pl", and "/cgi-bin/customer_service/complain.pl", but not to the script "/cgi-private/site_admin.pl". By default, path is set to "/", which causes the cookie to be sent to any CGI script on your site.

a "secure" flag

If the "secure" attribute is set, the cookie will only be sent to your script if the CGI request is occurring on a secure channel, such as SSL.

    $cookie = $query->cookie(-name=>'sessionID',
			     -value=>'xyzzy',
			     -expires=>'+1h',
			     -path=>'/cgi-bin/database',
			     -domain=>'.capricorn.org',
			     -secure=>1);
    print $query->header(-cookie=>$cookie);

-name

The name of the cookie (required). This can be any string at all. Although Netscape limits its cookie names to non-whitespace alphanumeric characters, CGI.pm removes this restriction by escaping and unescaping cookies behind the scenes.

-value

The value of the cookie. This can be any scalar value, array reference, or even associative array reference. For example, you can store an entire associative array into a cookie this way:

	$cookie=$query->cookie(-name=>'family information',
                               -value=>\%childrens_ages);

-path

The optional partial path for which this cookie will be valid, as described above.

-domain

The optional partial domain for which this cookie will be valid, as described above.

-expires

The optional expiration date for this cookie. The format is as described in the section on the header() method:

	"+1h"  one hour from now
      

-secure

If set to true, this cookie will only be used within a secure SSL session.

	print $query->header(-cookie=>$my_cookie);

	$cookie1 = $query->cookie(-name=>'riddle_name',
                                  -value=>"The Sphynx's Question");
        $cookie2 = $query->cookie(-name=>'answers',
                                  -value=>\%answers);
        print $query->header(-cookie=>[$cookie1,$cookie2]);

	use CGI;
	$query = new CGI;
	%answers = $query->cookie('answers');
	# $query->cookie(-name=>'answers') works too!

	foreach $name ($query->cookie()) {
            print $query->cookie($name);
        }

The cookie and CGI namespaces are separate. If you have a parameter named 'answers' and a cookie named 'answers', the values retrieved by param() and cookie() are independent of each other. However, it's simple to turn a CGI parameter into a cookie, and vice-versa:

   # turn a CGI parameter into a cookie
   $c=$q->cookie(-name=>'answers',-value=>[$q->param('answers')]);
   # vice-versa
   $q->param(-name=>'answers',-value=>[$q->cookie('answers')]);

See the cookie.cgi example script for some ideas on how to use cookies effectively.

NOTE: There are some limitations on cookies. Here is what RFC2109, section 6.3, states:

   Practical user agent implementations have limits on the number and
   size of cookies that they can store.  In general, user agents' cookie
   support should have no fixed limits.  They should strive to store as
   many frequently-used cookies as possible.  Furthermore, general-use
   user agents should provide each of the following minimum capabilities
   individually, although not necessarily simultaneously:

      * at least 300 cookies

      * at least 4096 bytes per cookie (as measured by the size of the
        characters that comprise the cookie non-terminal in the syntax
        description of the Set-Cookie header)

      * at least 20 cookies per unique host or domain name

   User agents created for specific purposes or for limited-capacity
   devices should provide at least 20 cookies of 4096 bytes, to ensure
   that the user can interact with a session-based origin server.

   The information in a Set-Cookie response header must be retained in
   its entirety.  If for some reason there is inadequate space to store
   the cookie, it must be discarded, not truncated.

   Applications should use as few and as small cookies as possible, and
   they should cope gracefully with the loss of a cookie.

Table of contents

Support for Frames

1. You can provide the name of a new or preexisting frame in the startform() and start_multipart_form() methods using the -target parameter. When the form is submitted, the output will be redirected to the indicated frame:

         print $query->start_form(-target=>'result_frame');
         

2. You can direct the output of a script into a new window or into a preexisting named frame by providing the name of the frame as a -target argument in the header method. For example, the following code will pop up a new window and display the script's output:

         $query = new CGI;
         print $query->header(-target=>'_blank');
         

   This feature is a non-standard extension to HTTP which is supported by Netscape browsers, but not by Internet Explorer.

The examples directory contains a script called popup.cgi that demonstrates a simple popup window. frameset.cgi provides a skeleton script for creating side-by-side query/result frame sets.

Support for JavaScript

You'll need to know JavaScript in order to use it. The Netscape JavaScript manual contains a good tutorial and reference guide to the JavaScript programming language.

The usual way to use JavaScript is to define a set of functions in a <SCRIPT> block inside the HTML header and then to register event handlers in the various elements of the page. Events include such things as the mouse passing over a form element, a button being clicked, the contents of a text field changing, or a form being submitted. When an event occurs that involves an element that has registered an event handler, its associated JavaScript code gets called.

The elements that can register event handlers include the <BODY> of an HTML document, hypertext links, all the various elements of a fill-out form, and the form itself. There are a large number of events, and each applies only to the elements for which it is relevant. Here is a partial list:

onLoad

The browser is loading the current document. Valid in:

• The HTML <BODY> section only.

onUnload

The browser is closing the current page or frame. Valid for:

• The HTML <BODY> section only.

onSubmit

The user has pressed the submit button of a form. This event happens just before the form is submitted, and your function can return a value of false in order to abort the submission. Valid for:

• Forms only.

onClick

The mouse has clicked on an item in a fill-out form. Valid for:

• Buttons (including submit, reset, and image buttons)
• Checkboxes
• Radio buttons

onChange

The user has changed the contents of a field. Valid for:

• Text fields
• Text areas
• Password fields
• File fields
• Popup Menus
• Scrolling lists

onFocus

The user has selected a field to work with. Valid for:

• Text fields
• Text areas
• Password fields
• File fields
• Popup Menus
• Scrolling lists

onBlur

The user has deselected a field (gone to work somewhere else). Valid for:

• Text fields
• Text areas
• Password fields
• File fields
• Popup Menus
• Scrolling lists

onSelect

The user has changed the part of a text field that is selected. Valid for:

• Text fields
• Text areas
• Password fields
• File fields

onMouseOver

The mouse has moved over an element.

• Text fields
• Text areas
• Password fields
• File fields
• Popup Menus
• Scrolling lists

onMouseOut

The mouse has moved off an element.

• Text fields
• Text areas
• Password fields
• File fields
• Popup Menus
• Scrolling lists

   print $q->textfield(-name=>'age',-onChange=>"validateAge(this)");

Similarly, you can create a form that checks itself over for consistency and alerts the user if some essential value is missing by creating it this way:

   print $q->startform(-onSubmit=>"validateMe(this)");

The JavaScript "standard" is still evolving, which means that new handlers may be added in the future, or may be present in some browsers and not in oth